ブール (Boolean) データ型

ブール値は true か false のいずれかの値です。また、状況に応じて、値 true は 1 に、false は 0 に変換されます。ブール値は、比較することによりスクリプトのフローを制御する論理演算子と共に使用されます。

次の例では、テキストファイルを SWF ファイルにロードし、テキストファイルが正しくロードされなかった場合は [出力] パネルにメッセージを表示し、正しくロードされた場合はパラメータを表示します。詳細については、コード例のコメントを参照してください。

var my_lv:LoadVars = new LoadVars();
//success はブール値
my_lv.onLoad = function(success:Boolean) {
    //success が true の場合は monthNames をトレース
    if (success) {
        trace(my_lv.monthNames);
    //success が false の場合はメッセージをトレース
    } else {
        trace("unable to load text file");
    }
};
my_lv.load("http://www.helpexamples.com/flash/params.txt");

次の例では、TextInput コンポーネントのインスタンスに入力された 2 つの値を検査しています。userNameEntered と isPasswordCorrect という 2 つのブール型変数を作成し、両方の変数が true に評価された場合は、String 変数 titleMessage に "Welcome" というメッセージを代入します。

// 2 つの TextInput コンポーネント、1 つの Label コンポーネント、および 1 つの Button コンポーネントをステージに追加
// この 3 つのコンポーネントインスタンスに厳密なデータ型を指定
var userName_ti:mx.controls.TextInput;
var password_ti:mx.controls.TextInput;
var submit_button:mx.controls.Button;
var welcome_lbl:mx.controls.Label;

//ラベルを非表示
welcome_lbl.visible = false;

//Button コンポーネントで使用するリスナーオブジェクトを作成
// ボタンがクリックされたら、ユーザー名とパスワードをチェック
var btnListener:Object = new Object();
btnListener.click = function(evt:Object) {
    // TextInput のインスタンスに 1 文字以上入力されていることを確認
    // ブール値 (true/false) を返す
    var userNameEntered:Boolean = (userName_ti.text.length>0);
    var isPasswordCorrect:Boolean = (password_ti.text == "vertigo");
    if (userNameEntered && isPasswordCorrect) {
        var titleMessage:String = "Welcome " + userName_ti.text + "!";
        welcome_lbl.text = titleMessage;
        //ラベルを表示
        welcome_lbl.visible = true;
    }
};
submit_button.addEventListener("click", btnListener);