cfparam

Description

Tests for the existence of a parameter (that is, a variable), validates its data, and, if a default value is not assigned, optionally provides one.

Syntax

<cfparam 
   name = "param_name"
   type = "data_type"
   default = "value"
max = "value"
min = "value"
pattern = "regular expression">

History

ColdFusion MX 7:

Added min, max, and pattern attributes.
Added creditcard, email, eurodate, float, integer, range, regex, regular_expression, ssn, social_security_number, time, URL, USdate, XML, and zipcode values of the type attribute.

Attributes

Attribute	Req/Opt	Default	Description
name	Required		Name of the parameter (variable) to test (such as "Client.Email " or "Cookie.BackgroundColor "). If omitted, and if the parameter does not exist, an error is thrown.
type	Optional	any	The valid format for the data; one of the following. For detailed information on validation algorithms, see Validating form data using hidden fields in Validating Data in ColdFusion MX Developer's Guide. any: any type of value. array: an array of values. binary: a binary value. boolean: a Boolean value: yes, no, true, false, or a number. creditcard: a 13-16 digit number conforming to the mod10 algorithm. date or time: a date-time value. email: a valid e-mail address. eurodate: a date-time value. Any date part must be in the format dd/mm/yy, The format can use /, -, or . characters as delimiters. float or numeric: a numeric value. guid: a Universally Unique Identifier of the form `"XXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXXX`" where '`X`' is a hexadecimal number. integer: an integer. query: a query object. range: a numeric range, specified by the `min` and `max` attributes. regex or regular_expression: matches input against `pattern` attribute. ssn or social_security_number: a U.S. social security number. string: a string value or single character. struct: a structure. telephone: a standard U.S. telephone number. URL: an http, https, ftp, file, mailto, or news URL. UUID: a ColdFusion Universally Unique Identifier, formatted '`XXXXXXXX-XXXX-XXXX-XXXXXXXXXXXXXXX`', where '`X`' is a hexadecimal number. See CreateUUID. USdate: a U.S. date of the format mm/dd/yy, with 1-2 digit days and months, 1-4 digit years. variableName: a string formatted according to ColdFusion variable naming conventions. xml: XML objects and XML strings. zipcode: U.S., 5- or 9-digit format ZIP codes.
default	Optional		Value to set parameter to if it does not exist. Any expression used for the default attribute is evaluated, even if the parameter exists. The result is not assigned if the parameter exists, but if the expression has side effects, they still occur.
max	Optional		The maximum valid value; used only for `range` validation.
min	Optional		The minimum valid value; used only for `range` validation.
pattern	Optional		A JavaScript regular expression that the parameter must match; used only for `regex` or `regular_expression` validation.

Usage

You can use this tag to make the following tests:

To test whether a required variable exists, use this tag with only the name attribute. If it does not exist, ColdFusion MX stops processing the page and returns an error.
To test whether a required variable exists, and that it is of the specified type, use this tag with the name and type attributes. If the variable does not exist or its value is not of the specified type, ColdFusion returns an error.
To set a default value for the variable, use this tag with the name and default attributes. If the variable does not exist, it is created and set to the default attribute value. If the variable exists, processing continues; the value is not changed.

If you specify variableName for the type attribute, the parameter's value must be a string that is in ColdFusion variable name format; that is, starts with a letter, underscore (_), or Unicode currency symbol, and contains letters, numbers, underscores, periods, and Unicode currency symbols, only. ColdFusion does not check whether the parameter value corresponds to an existing ColdFusion variable.

Tip: To improve performance, avoid using the cfparam tag in ColdFusion functions, including in CFC methods. Instead, place the cfparam tags in the body of the CFML pages.

Example

<!--- This example shows how to use CFPARAM to define default values for page
   variables. --------> 
<cfparam name = "storeTempVar" default = "my default value">
<cfparam name = "tempVar" default = "my default value">

<!--- Check if form.tempVar was passed. --->
<cfif IsDefined("form.tempVar") is "True">
   <!--- Check if form.tempVar is not blank. --->
   <cfif form.tempVar is not "">
      <!--- If not, set tempVar to value of form.tempVar --->
      <cfset tempVar = form.tempVar>
   </cfif>
</cfif>

<body>
<h3>cfparam Example</h3>
<p>cfparam is used to set default values so that a developer does not have to 
check for the existence of a variable using a function like IsDefined.

<p>The default value of our tempVar is 
   "<cfoutput>#StoreTempVar# </cfoutput>"

<!--- Check if tempVar is still the same as StoreTempVar.
and that tempVar is not blank --->
<cfif tempVar is not #StoreTempVar# 
   and tempVar is not "">
      <h3>The value of tempVar has changed: the new value is
      <cfoutput>#tempVar#</cfoutput></h3>
</cfif>

<p>
<form action = "cfparam.cfm" method = "post">
   Type in a new value for tempVar, and hit submit:<br>
   <input type = "Text" name = "tempVar">
   <input type = "Submit" name = "" value = "submit">
</form>

Version 7

Comments

pete_freitag said on Feb 9, 2005 at 1:44 PM :

The type="xml" was added in CFMX 7, but not listed in the history.

jrunrandy said on Feb 9, 2005 at 2:01 PM :

Thanks. I added bug 59809 for this.

shahzad said on Apr 13, 2007 at 1:25 PM :

it seems like default value is required because i keep getting the following error:
This page uses the CFPARAM tag to declare the parameter ABC as required for this template. The parameter is not available.Please verify that you have passed or initialized the parameter correctly. If you wish to set a default value for the parameter you should use the DEFAULT attribute of the CFPARAM tag.

when i have <cfparam name="abc" type="string">

the documentation says that it is an optional parameter

RSS feed | Send me an e-mail when comments are added to this page | Comment Report

Current page: http://livedocs.adobe.com/coldfusion/7/htmldocs/00000310.htm